Startseite → Logikrätsel → Ostereier → Lösung

Lösung: Ostereier

Rätsel einblenden

Lösung

Ausblenden

Schritt 1

  1. Nach neun Minuten hat Julia ihre zwei Ostereier gefunden.
Zeit 3 min 5 min 7 min 9 min 11 min
KindJulia
Farbe
Muster
Anzahl2

Übrig: Isabell, Luca, Mia, Paul, Blau, Gelb, Grün, Orange, Rot, Karos, Punkte, Sterne, Streifen, Wellen, 3, 4, 5, 6

Schritt 2

  1. Die gestreiften Eier wurden zwei Minuten, bevor Paul seine Ostereier fand, gefunden.
  2. Mia fand ihre Ostereier zwei Minuten, bevor die orangen Eier gefunden wurden.
  3. Isabell fand ihre Ostereier später als die Person, die gestreifte Eier gefunden hat.
  4. Luca fand seine Ostereier zwei Minuten, nachdem die mit einem Wellenmuster verzierten Eier gefunden worden waren.

Paul, Isabell und Luca können ihre Eier also nicht bereits nach drei Minuten gefunden haben.

Zeit 3 min 5 min 7 min 9 min 11 min
KindMiaJulia
FarbeOrange
Muster
Anzahl2

Übrig: Isabell, Luca, Paul, Blau, Gelb, Grün, Rot, Karos, Punkte, Sterne, Streifen, Wellen, 3, 4, 5, 6

Schritt 3

  1. Paul hat drei Ostereier gefunden.
  2. Das Kind, das seine / ihre Eier zuerst fand, fand weniger als fünf Eier.

Übrig bleibt für Mia also nur die Möglichkeit, dass sie vier Eier gefunden hat.

Zeit 3 min 5 min 7 min 9 min 11 min
KindMiaJulia
FarbeOrange
Muster
Anzahl42

Übrig: Isabell, Luca, Paul, Blau, Gelb, Grün, Rot, Karos, Punkte, Sterne, Streifen, Wellen, 3, 5, 6

Schritt 4

  1. Die gelben Eier wurden früher gefunden als die, die mit einem Karomuster verziert waren.
  2. Die mit einem Karomuster verzierten Eier wurden vier Minuten früher als die mit Sternen verzierten Ostereier gefunden.

Die mit einem Karomuster verzierten Eier müssen also nach spätestens 7 Minuten gefunden worden sein. Für die gelben Eier bleibt dann nur noch eine Möglichkeit übrig.

Zeit 3 min 5 min 7 min 9 min 11 min
KindMiaJulia
FarbeGelbOrange
Muster
Anzahl42

Übrig: Isabell, Luca, Paul, Blau, Grün, Rot, Karos, Punkte, Sterne, Streifen, Wellen, 3, 5, 6

Schritt 5

  1. Die roten Eier waren mit einem Wellenmuster verziert.
  2. Luca fand seine Ostereier zwei Minuten, nachdem die mit einem Wellenmuster verzierten Eier gefunden worden waren.

Für diese Kombination gibt es nur noch eine Möglichkeit.

Zeit 3 min 5 min 7 min 9 min 11 min
KindMiaJuliaLuca
FarbeGelbOrangeRot
MusterWellen
Anzahl42

Übrig: Isabell, Paul, Blau, Grün, Karos, Punkte, Sterne, Streifen, 3, 5, 6

Schritt 6

  1. Die gelben Eier wurden früher gefunden als die, die mit einem Karomuster verziert waren.
  2. Die mit einem Karomuster verzierten Eier wurden vier Minuten früher als die mit Sternen verzierten Ostereier gefunden.

Damit steht nun auch fest, wann die mit Karos und Sternen verzierten Eier gefunden wurden:

Zeit 3 min 5 min 7 min 9 min 11 min
KindMiaJuliaLuca
FarbeGelbOrangeRot
MusterKarosWellenSterne
Anzahl42

Übrig: Isabell, Paul, Blau, Grün, Punkte, Streifen, 3, 5, 6

Schritt 7

  1. Die Eier mit einem Sternenmuster wurden später gefunden als die blauen Ostereier.
Zeit 3 min 5 min 7 min 9 min 11 min
KindMiaJuliaLuca
FarbeGelbOrangeBlauRotGrün
MusterKarosWellenSterne
Anzahl42

Übrig: Isabell, Paul, Punkte, Streifen, 3, 5, 6

Schritt 8

  1. Die gestreiften Eier wurden zwei Minuten, bevor Paul seine Ostereier fand, gefunden.
  2. Isabell fand ihre Ostereier später als die Person, die gestreifte Eier gefunden hat.

Damit muss Paul früher als Isabell fündig geworden sein.

Zeit 3 min 5 min 7 min 9 min 11 min
KindMiaPaulIsabellJuliaLuca
FarbeGelbOrangeBlauRotGrün
MusterStreifenPunkteKarosWellenSterne
Anzahl42

Übrig: 3, 5, 6

Schritt 9

  1. Paul hat drei Ostereier gefunden.
Zeit 3 min 5 min 7 min 9 min 11 min
KindMiaPaulIsabellJuliaLuca
FarbeGelbOrangeBlauRotGrün
MusterStreifenPunkteKarosWellenSterne
Anzahl432

Übrig: 5, 6

Ausblenden

Schritt 10

  1. Das Kind, das sechs Ostereier gefunden hat, fand diese, bevor Luca seine Ostereier fand.
Zeit 3 min 5 min 7 min 9 min 11 min
KindMiaPaulIsabellJuliaLuca
FarbeGelbOrangeBlauRotGrün
MusterStreifenPunkteKarosWellenSterne
Anzahl43625

Lösungssuche mit Prolog

Dieses Rätsel lässt sich gut mit Hilfe der logischen Programmiersprache „Prolog“ lösen:

Prolog-Code
  1. % directlybefore(A, B, L):
  2. % A steht in der Liste L direkt links von B.
  3. directlybefore(A, B, [A, B | _]).
  4. directlybefore(A, B, [_ | R]) :- directlybefore(A, B, R).

  6. % directlyafter(A, B, L):
  7. % A steht in der Liste L direkt rechts von B.
  8. directlyafter(A, B, L) :- directlybefore(B, A, L).

  10. % before(A, B, L)
  11. % A steht in der Liste L weiter links als B.
  12. before(A, B, [A | R]) :- member(B, R).
  13. before(A, B, [_ | R]) :- before(A, B, R).

  15. % after(A, B, L)
  16. % A steht in der Liste L weiter rechts als B.
  17. after(A, B, L) :- before(B, A, L).

  19. % Implementierung des Rätsels
  20. ostereier :-
  21.   % Definition der Kombinationen
  22.   Ostereier = [Drei, Fuenf, Sieben, Neun, Elf],

  24.   % Nach 3 Minuten gefunden
  25.   Drei = [3, Kind1, Farbe1, Muster1, Anzahl1],

  27.   % Nach 5 Minuten gefunden
  28.   Fuenf = [5, Kind2, Farbe2, Muster2, Anzahl2],

  30.   % Nach 7 Minuten gefunden
  31.   Sieben = [7, Kind3, Farbe3, Muster3, Anzahl3],

  33.   % Nach 9 Minuten gefunden
  34.   Neun = [9, Kind4, Farbe4, Muster4, Anzahl4],

  36.   % Nach 11 Minuten gefunden
  37.   Elf = [11, Kind5, Farbe5, Muster5, Anzahl5],

  39.   % Definition der Anzahlen
  40.   permutation(
  41.   [Anzahl1, Anzahl2, Anzahl3, Anzahl4, Anzahl5],
  42.   [2, 3, 4, 5, 6]
  43.   ),

  45.   % Paul hat drei Ostereier gefunden.
  46.   member([_, paul, _, _, 3], Ostereier),

  48.   % Die gelben Eier wurden früher gefunden als die, die mit
  49.   % einem Karomuster verziert waren.
  50.   before([_, _, gelb, _, _], [_, _, _, karos, _], Ostereier),

  52.   % Nach neun Minuten hat Julia ihre zwei Ostereier gefunden.
  53.   Neun = [9, julia, _, _, 2],

  55.   % Die gestreiften Eier wurden zwei Minuten, bevor Paul
  56.   % seine Ostereier fand, gefunden.
  57.   directlybefore([_, _, _, streifen, _], [_, paul, _, _, _], Ostereier),

  59.   % Die roten Eier waren mit einem Wellenmuster verziert.
  60.   member([_, _, rot, wellen, _], Ostereier),

  62.   % Mia fand ihre Ostereier zwei Minuten, bevor die orangen
  63.   % Eier gefunden wurden.
  64.   directlybefore([_, mia, _, _, _], [_, _, orange, _, _], Ostereier),

  66.   % Die Eier mit einem Sternenmuster wurden später gefunden
  67.   % als die blauen Ostereier.
  68.   after([_, _, _, sterne, _], [_, _, blau, _, _], Ostereier),

  70.   % Die mit einem Karomuster verzierten Eier wurden vier
  71.   % Minuten früher als die mit Sternen verzierten Ostereier
  72.   % gefunden.
  73.   member([Z1, _, _, karos, _], Ostereier),
  74.   member([Z2, _, _, sterne, _], Ostereier),
  75.   Z2 is Z1 + 4,

  77.   % Das Kind, das sechs Ostereier gefunden hat, fand diese,
  78.   % bevor Luca seine Ostereier fand.
  79.   before([_, _, _, _, 6], [_, luca, _, _, _], Ostereier),

  81.   % Isabell fand ihre Ostereier später als die Person, die
  82.   % gestreifte Eier gefunden hat.
  83.   after([_, isabell, _, _, _], [_, _, _, streifen, _], Ostereier),

  85.   % Das Kind, das seine / ihre Eier zuerst fand, fand weniger
  86.   % als fünf Eier.
  87.   Drei = [3, _, _, _, A2],
  88.   A2 < 5,

  90.   % Luca fand seine Ostereier zwei Minuten, nachdem die mit
  91.   % einem Wellenmuster verzierten Eier gefunden worden waren.
  92.   directlyafter([_, luca, _, _, _], [_, _, _, wellen, _], Ostereier),

  94.   % Definition der Namen
  95.   permutation(
  96.   [Kind1, Kind2, Kind3, Kind4, Kind5],
  97.   [isabell, julia, luca, mia, paul]
  98.   ),

  100.   % Definition der Farben
  101.   permutation(
  102.   [Farbe1, Farbe2, Farbe3, Farbe4, Farbe5],
  103.   [blau, gelb, gruen, orange, rot]
  104.   ),

  106.   % Definition der Muster
  107.   permutation(
  108.   [Muster1, Muster2, Muster3, Muster4, Muster5],
  109.   [karos, punkte, sterne, streifen, wellen]
  110.   ),

  112.   % Loesung ausgeben
  113.   write(Ostereier),
  114.   write('\n'),

  116.   % Weitere Loesungen suchen
  117.   fail.