Startseite → Logikrätsel → Im Büro → Lösung

Lösung: Im Büro

Rätsel einblenden

Lösung

Ausblenden

Schritt 1

  1. Der/die Fotograf/in verdient 4000 € pro Monat und sitzt auf dem zweiten Platz von rechts.
  2. Der/die Kundenberater/in sitzt auf dem Platz ganz links außen und kam zuletzt ins Büro.
Platz von links 1 2 3 4 5
Person
BerufKundenberater/inFotograf/in
Ankunft8:00 Uhr
Gericht
Gehalt4000 €

Übrig: Alina, Björn, Fabian, Michelle, Vanessa, Einkäufer/in, Grafikdesigner/in, Webentwickler/in, 7:00 Uhr, 7:15 Uhr, 7:30 Uhr, 7:45 Uhr, Currywurst, Erbsensuppe, Hamburger, Pizza, Spaghetti, 3600 €, 3800 €, 3900 €, 4200 €

Schritt 2

  1. Die Personen mit dem höchsten bzw. niedrigsten Gehalt sitzen direkt nebeneinander.
  2. Die Person, die mittags Erbsensuppe gegessen hat, verdient 3800 € pro Monat.
  3. Die Person, die auf dem Platz rechts außen sitzt, hat mittags nicht Erbsensuppe gegessen.

Die Person auf dem Platz rechts außen muss also 3900 € pro Monat verdienen.

Platz von links 1 2 3 4 5
Person
BerufKundenberater/inFotograf/in
Ankunft8:00 Uhr
Gericht
Gehalt4000 €3900 €

Übrig: Alina, Björn, Fabian, Michelle, Vanessa, Einkäufer/in, Grafikdesigner/in, Webentwickler/in, 7:00 Uhr, 7:15 Uhr, 7:30 Uhr, 7:45 Uhr, Currywurst, Erbsensuppe, Hamburger, Pizza, Spaghetti, 3600 €, 3800 €, 4200 €

Schritt 3

  1. Fabian, der um 7:45 Uhr in des Büro kam, sitzt direkt links neben der Person, die Pizza gegessen hat.
  2. Die Person, die Spaghetti gegessen hat, sitzt weiter rechts als der/die Grafikdesigner/in.
  3. Björn, der nicht auf dem zweiten Platz von links sitzt, aß mittags einen Hamburger.
  4. Die Personen mit dem höchsten bzw. niedrigsten Gehalt sitzen direkt nebeneinander.
  5. Die Person, die mittags Erbsensuppe gegessen hat, verdient 3800 € pro Monat.

Fabian kann nicht auf dem ersten Platz von links sitzen, deshalb kann die Person auf dem zweiten Platz von links keine Pizza gegessen haben. Da der/die Grafikdesigner/in nicht auf dem ersten Platz von links sitzt, kommt für den zweiten Platz von links auch das Gericht „Spaghetti“ nicht in Frage. Ebenso sind Hamburger hier nicht möglich. Da die Personen mit dem höchsten bzw. niedrigsten Gehalt nebeneinander sitzen, können auf dem zweiten Platz von links nicht 3800 € pro Monat verdient werden, weshalb auch die Erbsensuppe hier nicht möglich ist. Übrig bleibt nur die Currywurst.

Platz von links 1 2 3 4 5
Person
BerufKundenberater/inFotograf/in
Ankunft8:00 Uhr
GerichtCurrywurst
Gehalt4000 €3900 €

Übrig: Alina, Björn, Fabian, Michelle, Vanessa, Einkäufer/in, Grafikdesigner/in, Webentwickler/in, 7:00 Uhr, 7:15 Uhr, 7:30 Uhr, 7:45 Uhr, Erbsensuppe, Hamburger, Pizza, Spaghetti, 3600 €, 3800 €, 4200 €

Schritt 4

  1. Der/die Einkäufer/in sitzt direkt neben der Person, die mittags eine Currywurst gegessen hat.
Platz von links 1 2 3 4 5
Person
BerufKundenberater/inEinkäufer/inFotograf/in
Ankunft8:00 Uhr
GerichtCurrywurst
Gehalt4000 €3900 €

Übrig: Alina, Björn, Fabian, Michelle, Vanessa, Grafikdesigner/in, Webentwickler/in, 7:00 Uhr, 7:15 Uhr, 7:30 Uhr, 7:45 Uhr, Erbsensuppe, Hamburger, Pizza, Spaghetti, 3600 €, 3800 €, 4200 €

Schritt 5

  1. Die Person, die Spaghetti gegessen hat, sitzt weiter rechts als der/die Grafikdesigner/in.

Der/die Grafikdesigner/in sitzt also nicht rechts außen.

Platz von links 1 2 3 4 5
Person
BerufKundenberater/inGrafikdesigner/inEinkäufer/inFotograf/inWebentwickler/in
Ankunft8:00 Uhr
GerichtCurrywurst
Gehalt4000 €3900 €

Übrig: Alina, Björn, Fabian, Michelle, Vanessa, 7:00 Uhr, 7:15 Uhr, 7:30 Uhr, 7:45 Uhr, Erbsensuppe, Hamburger, Pizza, Spaghetti, 3600 €, 3800 €, 4200 €

Schritt 6

  1. Fabian, der um 7:45 Uhr in des Büro kam, sitzt direkt links neben der Person, die Pizza gegessen hat.
  2. Alinas Gehalt ist höher als das der Person, die erst um 8:00 Uhr ins Büro kam.
  3. Michelle kam 15 Minuten später ins Büro als der/die Webentwickler/in.
  4. Vanessa kam früher ins Büro als die Person, die direkt rechts neben ihr sitzt.

Weder Fabian, Alina noch Vanessa können um 8:00 Uhr zur Arbeit gekommen sein. Angenommen, Michelle wäre um 8:00 Uhr zur Arbeit gekommen, dann wäre der/die Webentwickler/in um 7:45 Uhr angekommen. Das müsste Fabian sein, der dann ganz rechts sitzen würde. Dies wäre aber ein Widerspruch dazu, dass Fabian links von der Person sitzt, die Pizza gegessen hat. Folglich bleibt für den ersten Platz von links nur Björn übrig.

Platz von links 1 2 3 4 5
PersonBjörn
BerufKundenberater/inGrafikdesigner/inEinkäufer/inFotograf/inWebentwickler/in
Ankunft8:00 Uhr
GerichtCurrywurst
Gehalt4000 €3900 €

Übrig: Alina, Fabian, Michelle, Vanessa, 7:00 Uhr, 7:15 Uhr, 7:30 Uhr, 7:45 Uhr, Erbsensuppe, Hamburger, Pizza, Spaghetti, 3600 €, 3800 €, 4200 €

Schritt 7

  1. Björn, der nicht auf dem zweiten Platz von links sitzt, aß mittags einen Hamburger.
Platz von links 1 2 3 4 5
PersonBjörn
BerufKundenberater/inGrafikdesigner/inEinkäufer/inFotograf/inWebentwickler/in
Ankunft8:00 Uhr
GerichtHamburgerCurrywurst
Gehalt4000 €3900 €

Übrig: Alina, Fabian, Michelle, Vanessa, 7:00 Uhr, 7:15 Uhr, 7:30 Uhr, 7:45 Uhr, Erbsensuppe, Pizza, Spaghetti, 3600 €, 3800 €, 4200 €

Schritt 8

  1. Die Person, die mittags Erbsensuppe gegessen hat, verdient 3800 € pro Monat.
Platz von links 1 2 3 4 5
PersonBjörn
BerufKundenberater/inGrafikdesigner/inEinkäufer/inFotograf/inWebentwickler/in
Ankunft8:00 Uhr
GerichtHamburgerCurrywurstErbsensuppe
Gehalt3800 €4000 €3900 €

Übrig: Alina, Fabian, Michelle, Vanessa, 7:00 Uhr, 7:15 Uhr, 7:30 Uhr, 7:45 Uhr, Pizza, Spaghetti, 3600 €, 4200 €

Schritt 9

  1. Alinas Gehalt ist höher als das der Person, die erst um 8:00 Uhr ins Büro kam.

Folglich kann Björns Gehalt nicht 4200 € pro Monat betragen.

Platz von links 1 2 3 4 5
PersonBjörn
BerufKundenberater/inGrafikdesigner/inEinkäufer/inFotograf/inWebentwickler/in
Ankunft8:00 Uhr
GerichtHamburgerCurrywurstErbsensuppe
Gehalt3600 €4200 €3800 €4000 €3900 €

Übrig: Alina, Fabian, Michelle, Vanessa, 7:00 Uhr, 7:15 Uhr, 7:30 Uhr, 7:45 Uhr, Pizza, Spaghetti

Schritt 10

  1. Das Gehalt der Person, die das Büro zuerst betreten hat, liegt unter dem Durchschnittsgehalt der fünf Personen.

Das Durchschnittsgehalt der fünf beträgt 3900 € pro Monat. Also kann nur die Person auf dem mittleren Platz um 7:00 Uhr gekommen sein.

Platz von links 1 2 3 4 5
PersonBjörn
BerufKundenberater/inGrafikdesigner/inEinkäufer/inFotograf/inWebentwickler/in
Ankunft8:00 Uhr7:00 Uhr
GerichtHamburgerCurrywurstErbsensuppe
Gehalt3600 €4200 €3800 €4000 €3900 €

Übrig: Alina, Fabian, Michelle, Vanessa, 7:15 Uhr, 7:30 Uhr, 7:45 Uhr, Pizza, Spaghetti

Schritt 11

  1. Fabian, der um 7:45 Uhr in des Büro kam, sitzt direkt links neben der Person, die Pizza gegessen hat.
Platz von links 1 2 3 4 5
PersonBjörnFabian
BerufKundenberater/inGrafikdesigner/inEinkäufer/inFotograf/inWebentwickler/in
Ankunft8:00 Uhr7:00 Uhr7:45 Uhr
GerichtHamburgerCurrywurstErbsensuppeSpaghettiPizza
Gehalt3600 €4200 €3800 €4000 €3900 €

Übrig: Alina, Michelle, Vanessa, 7:15 Uhr, 7:30 Uhr

Schritt 12

  1. Michelle kam 15 Minuten später ins Büro als der/die Webentwickler/in.
Platz von links 1 2 3 4 5
PersonBjörnMichelleFabian
BerufKundenberater/inGrafikdesigner/inEinkäufer/inFotograf/inWebentwickler/in
Ankunft8:00 Uhr7:30 Uhr7:00 Uhr7:45 Uhr7:15 Uhr
GerichtHamburgerCurrywurstErbsensuppeSpaghettiPizza
Gehalt3600 €4200 €3800 €4000 €3900 €

Übrig: Alina, Vanessa

Ausblenden

Schritt 13

  1. Vanessa kam früher ins Büro als die Person, die direkt rechts neben ihr sitzt.
Platz von links 1 2 3 4 5
PersonBjörnMichelleVanessaFabianAlina
BerufKundenberater/inGrafikdesigner/inEinkäufer/inFotograf/inWebentwickler/in
Ankunft8:00 Uhr7:30 Uhr7:00 Uhr7:45 Uhr7:15 Uhr
GerichtHamburgerCurrywurstErbsensuppeSpaghettiPizza
Gehalt3600 €4200 €3800 €4000 €3900 €

Lösungssuche mit Prolog

Dieses Rätsel lässt sich gut mit Hilfe der logischen Programmiersprache „Prolog“ lösen:

Prolog-Code
  1. % directlyleftof(A, B, L):
  2. % A steht in der Liste L direkt links von B.
  3. directlyleftof(A, B, [A, B | _]).
  4. directlyleftof(A, B, [_ | R]) :- directlyleftof(A, B, R).

  6. % directlyrightof(A, B, L):
  7. % A steht in der Liste L direkt rechts von B.
  8. directlyrightof(A, B, L) :- directlyleftof(B, A, L).

  10. % nextto(A, B, L):
  11. % A steht in der Liste L direkt neben B.
  12. nextto(A, B, L) :- directlyleftof(A, B, L); directlyleftof(B, A, L).

  14. % leftof(A, B, L)
  15. % A steht in der Liste L weiter links als B.
  16. leftof(A, B, [A | R]) :- member(B, R).
  17. leftof(A, B, [_ | R]) :- leftof(A, B, R).

  19. % rightof(A, B, L)
  20. % A steht in der Liste L weiter rechts als B.
  21. rightof(A, B, L) :- leftof(B, A, L).

  23. % Implementierung des Rätsels
  24. buero :-
  25.   % Definition der Sitzplätze
  26.   Buero = [Eins, Zwei, Drei, Vier, Fuenf],

  28.   % Erster Platz von links
  29.   Eins = [Person1, Beruf1, Zeit1, Gericht1, Gehalt1],

  31.   % Zweiter Platz von links
  32.   Zwei = [Person2, Beruf2, Zeit2, Gericht2, Gehalt2],

  34.   % Dritter Platz von links
  35.   Drei = [Person3, Beruf3, Zeit3, Gericht3, Gehalt3],

  37.   % Vierter Platz von links
  38.   Vier = [Person4, Beruf4, Zeit4, Gericht4, Gehalt4],

  40.   % Fünfter Platz von links
  41.   Fuenf = [Person5, Beruf5, Zeit5, Gericht5, Gehalt5],

  43.   % Definition der Ankunftszeiten: Minuten ab 7:00 Uhr
  44.   permutation(
  45.   [Zeit1, Zeit2, Zeit3, Zeit4, Zeit5],
  46.   [0, 15, 30, 45, 60]
  47.   ),

  49.   % Definition der Gehälter
  50.   permutation(
  51.   [Gehalt1, Gehalt2, Gehalt3, Gehalt4, Gehalt5],
  52.   [3600, 3800, 3900, 4000, 4200]
  53.   ),

  55.   % Fabian, der um 7:45 Uhr in des Büro kam, sitzt direkt
  56.   % links neben der Person, die Pizza gegessen hat.
  57.   directlyleftof([fabian, _, 45, _, _], [_, _, _, pizza, _], Buero),

  59.   % Alinas Gehalt ist höher als das der Person,
  60.   % die erst um 8:00 Uhr ins Büro kam.
  61.   member([alina, _, _, _, GehaltA], Buero),
  62.   member([_, _, 60, _, GehaltB], Buero),
  63.   GehaltA > GehaltB,

  65.   % Die Person, die Spaghetti gegessen hat, sitzt weiter rechts
  66.   % als der/die Grafikdesigner/in.
  67.   rightof([_, _, _, spaghetti, _], [_, grafikdesigner, _, _, _], Buero),

  69.   % Der/die Fotograf/in verdient 4000 € pro Monat und sitzt auf dem
  70.   % zweiten Platz von rechts.
  71.   Vier = [_, fotograf, _, _, 4000],

  73.   % Michelle kam 15 Minuten später ins Büro als der/die Webentwickler/in.
  74.   member([michelle, _, ZeitA, _, _], Buero),
  75.   member([_, webentwickler, ZeitB, _, _], Buero),
  76.   ZeitA is ZeitB + 15,

  78.   % Björn, der nicht auf dem zweiten Platz von links sitzt,
  79.   % aß mittags einen Hamburger.
  80.   member(Person2, [alina, fabian, michelle, vanessa]),
  81.   member([bjoern, _, _, hamburger, _], Buero),

  83.   % Vanessa kam früher ins Büro als die Person, die direkt
  84.   % rechts neben ihr sitzt.
  85.   directlyrightof([_, _, ZeitC, _, _], [vanessa, _, ZeitD, _, _], Buero),
  86.   ZeitD < ZeitC,

  88.   % Die Personen mit dem höchsten bzw. niedrigsten Gehalt sitzen
  89.   % direkt nebeneinander.
  90.   nextto([_, _, _, _, 3600], [_, _, _, _, 4200], Buero),

  92.   % Der/die Kundenberater/in sitzt auf dem Platz ganz links außen
  93.   % und kam zuletzt ins Büro.
  94.   Eins = [_, kundenberater, 60, _, _],

  96.   % Die Person, die mittags Erbsensuppe gegessen hat, verdient
  97.   % 3800 € pro Monat.
  98.   member([_, _, _, erbsensuppe, 3800], Buero),

  100.   % Der/die Einkäuferin sitzt direkt neben der Person, die mittags
  101.   % eine Currywurst gegessen hat.
  102.   nextto([_, einkaeufer, _, _, _], [_, _, _, currywurst, _], Buero),

  104.   % Die Person, die auf dem Platz rechts außen sitzt,
  105.   % hat mittags nicht Erbsensuppe gegessen.
  106.   member(Gericht5, [currywurst, hamburger, pizza, spaghetti]),

  108.   % Das Gehalt der Person, die das Büro zuerst betreten hat, liegt
  109.   % unter dem Durchschnittsgehalt der fünf Personen.
  110.   member([_, _, 0, _, GehaltC], Buero),
  111.   GehaltC < 3900,

  113.   % Definition der Namen
  114.   permutation(
  115.   [Person1, Person2, Person3, Person4, Person5],
  116.   [alina, bjoern, fabian, michelle, vanessa]
  117.   ),

  119.   % Definition der Berufe
  120.   permutation(
  121.   [Beruf1, Beruf2, Beruf3, Beruf4, Beruf5],
  122.   [einkaeufer, fotograf, grafikdesigner, kundenberater, webentwickler]
  123.   ),

  125.   % Definition der Gerichte
  126.   permutation(
  127.   [Gericht1, Gericht2, Gericht3, Gericht4, Gericht5],
  128.   [currywurst, erbsensuppe, hamburger, pizza, spaghetti]
  129.   ),

  131.   % Loesung ausgeben
  132.   write(Buero),
  133.   write('\n'),

  135.   % Weitere Loesungen suchen
  136.   fail.