Linkweg: Home / Logikrätsel / Das Einsteinrätsel / Lösung

Das Einsteinrätsel

Lösung

Hier möchte ich Ihnen einen möglichen Lösungsweg für das Einsteinrätsel vorstellen. Sollte Ihnen ein Schritt undurchsichtig sein, dann können Sie im Thread "Einsteinrätsel" nachfragen.

• direkt zur Lösung

Schritt 1

• Der Mann im mittleren Haus trinkt Milch.

übrig: gelb; blau; rot; grün; weiß; Norweger; Däne; Brite; Deutscher; Schwede; Wasser; Tee; Kaffee; Bier; Dunhill; Marlboro; Pall Mall; Rothmanns; Winfield; Katze; Pferd; Vogel; Fisch; Hund;

Schritt 2

• Der Norweger lebt im ersten Haus.

übrig: gelb; blau; rot; grün; weiß; Däne; Brite; Deutscher; Schwede; Wasser; Tee; Kaffee; Bier; Dunhill; Marlboro; Pall Mall; Rothmanns; Winfield; Katze; Pferd; Vogel; Fisch; Hund;

Schritt 3

• Der Norweger wohnt neben dem blauen Haus.

übrig: gelb; rot; grün; weiß; Däne; Brite; Deutscher; Schwede; Wasser; Tee; Kaffee; Bier; Dunhill; Marlboro; Pall Mall; Rothmanns; Winfield; Katze; Pferd; Vogel; Fisch; Hund;

Schritt 4

• Das grüne Haus steht (direkt) links neben dem weißen Haus.
• Der Besitzer des grünen Hauses trinkt Kaffee.

Wenn das grüne Haus direkt links vom weißen Haus steht, dann muss das grüne Haus Nr. 3 oder Nr. 4 sein. Weiß wäre demnach das Haus Nr. 4 bzw. das Haus Nr. 5. Da im grünen Haus Kaffee getrunken wird, muss das grüne Haus Nr. 4 sein, denn in Nr. 3 wird Milch getrunken.

übrig: gelb; rot; Däne; Brite; Deutscher; Schwede; Wasser; Tee; Bier; Dunhill; Marlboro; Pall Mall; Rothmanns; Winfield; Katze; Pferd; Vogel; Fisch; Hund;

Schritt 5

• Der Brite lebt im roten Haus.

Da der Brite im roten Haus wohnt, muss dieses Haus Nr. 3 sein, denn im Haus Nr. 1 lebt der Norweger. Folglich bleibt für Haus Nr. 1 auch nur noch die Farbe gelb übrig.

übrig: Däne; Deutscher; Schwede; Wasser; Tee; Bier; Dunhill; Marlboro; Pall Mall; Rothmanns; Winfield; Katze; Pferd; Vogel; Fisch; Hund;

Schritt 6

• Der Bewohner des gelben Hauses raucht Dunhill.

übrig: Däne; Deutscher; Schwede; Wasser; Tee; Bier; Marlboro; Pall Mall; Rothmanns; Winfield; Katze; Pferd; Vogel; Fisch; Hund;

Schritt 7

• Der Mann mit dem Pferd lebt neben der Person, die Dunhill raucht.

übrig: Däne; Deutscher; Schwede; Wasser; Tee; Bier; Marlboro; Pall Mall; Rothmanns; Winfield; Katze; Vogel; Fisch; Hund;

Schritt 8

• Der Däne trinkt gern Tee.
• Der Winfield-Raucher trinkt gern Bier.

Im Haus Nr. 1 wohnt weder der Däne, noch raucht die betreffende Person Winfield. Folglich bleibt für sie nur das Wasser übrig.

übrig: Däne; Deutscher; Schwede; Tee; Bier; Marlboro; Pall Mall; Rothmanns; Winfield; Katze; Vogel; Fisch; Hund;

Schritt 9

• Der Marlboro-Raucher hat einen Nachbarn, der Wasser trinkt.

übrig: Däne; Deutscher; Schwede; Tee; Bier; Pall Mall; Rothmanns; Winfield; Katze; Vogel; Fisch; Hund;

Schritt 10

• Der Winfield-Raucher trinkt gern Bier.

Beides zusammen ist nur in Haus Nr. 5 möglich.

übrig: Däne; Deutscher; Schwede; Tee; Pall Mall; Rothmanns; Katze; Vogel; Fisch; Hund;

Schritt 11

• Der Däne trinkt gern Tee.

Beides zusammen ist nur in Haus Nr. 2 möglich.

übrig: Deutscher; Schwede; Pall Mall; Rothmanns; Katze; Vogel; Fisch; Hund;

Schritt 12

• Der Deutsche raucht Rothmanns.

Beides zusammen ist nur in Haus Nr. 4 möglich.

übrig: Schwede; Pall Mall; Katze; Vogel; Fisch; Hund;

Schritt 13

• Der Schwede hält sich einen Hund.

Beides zusammen ist nur in Haus Nr. 5 möglich.

übrig: Pall Mall; Katze; Vogel; Fisch;

Schritt 14

• Die Person, die Pall Mall raucht, hat einen Vogel.

Beides zusammen ist nur in Haus Nr. 3 möglich.

übrig: Katze; Fisch;

Schritt 15

• Der Marlboro-Raucher wohnt neben der Person mit der Katze.

übrig: Fisch;

Schritt 16

Nun bleibt nur noch eine Lücke für den Fisch. Die Frage ist also beantwortet:
Der Kaffee trinkende, Rothmanns rauchende Deutsche aus dem grünen Haus hält den Fisch!

Lösungssuche mit Prolog

Das Einsteinrätsel ist gut geeignet, um es in einer logischen Programmiersprache wie Prolog zu implementieren. Das folgende Programm sucht nach der Lösung.

% A steht links neben B
leftof(A,B,[A,B|_]).
leftof(A,B,[_|R]) :- leftof(A,B,R).
 
% A steht neben B
nextto(A,B,H) :- leftof(A,B,H); leftof(B,A,H).
 
% A ist das erste Haus
first(A,[A|_]).
 
% A steht in der Mitte
inthemiddle(A,[_,_,A,_,_]).
 
% Das Raetsel
einstein :-
  % 5 Haeuser stehen nebeneinander
  H = [_,_,_,_,_],
  % Der Brite lebt im roten Haus
  member([brite,rot,_,_,_],H),
  % Der Schwede haelt sich einen Hund
  member([schwede,_,hund,_,_],H),
  % Der Daene trinkt gern Tee
  member([daene,_,_,tee,_],H),
  % Das gruene Haus steht links neben dem weissen Haus
  leftof([_,gruen,_,_,_],[_,weiss,_,_,_],H),
  % Der Besitzer des gruenen Hauses trinkt Kaffee
  member([_,gruen,_,kaffee,_],H),
  % Die Person, die Pall Mall raucht, hat einen Vogel
  member([_,_,vogel,_,pallmall],H),
  % Der Mann im mittleren Haus trinkt Milch
  inthemiddle([_,_,_,milch,_],H),
  % Der Bewohner des gelben Hauses raucht Dunhill
  member([_,gelb,_,_,dunhill],H),
  % Der Norweger lebt im ersten Haus.
  first([norweger,_,_,_,_],H),
  % Der Marlboro-Raucher wohnt neben der Person mit der Katze
  nextto([_,_,_,_,marlboro],[_,_,katze,_,_],H),
  % Der Mann mit dem Pferd lebt neben der Person, die Dunhill raucht
  nextto([_,_,pferd,_,_],[_,_,_,_,dunhill],H),
  % Der Winfield-Raucher trinkt gern Bier
  member([_,_,_,bier,winfield],H),
  % Der Norweger wohnt neben dem blauen Haus
  nextto([norweger,_,_,_,_],[_,blau,_,_,_],H),
  % Der Deutsche raucht Rothmanns
  member([deutsche,_,_,_,rothmanns],H),
  % Der Marlboro-Raucher hat einen Nachbarn, der Wasser trinkt
  nextto([_,_,_,_,marlboro],[_,_,_,wasser,_],H),
  % Wem gehoert der Fisch?
  member([N,_,fisch,_,_],H),
  write('Der '), write(N), write(' haelt den Fisch.'), !.